Tutorial de Rigging - Parte 1 (Joints) - Spiderman

Описание: //*************************************************************************************************************
// Title: jh_dispLocalAxis.mel
// Author: Jorn-Harald Paulsen
// Created: January 27, 2012
// Last Update: January 27, 2012
// Description: Utility to display or hide the local rotation axis of the selected object(s)
//*************************************************************************************************************
// MAIN WINDOW
//*************************************************************************************************************
global proc jh_dispLocalAxis()
{
//Delete window if it already exists
if (`window -q -ex jh_dispLocalAxis`) deleteUI jh_dispLocalAxis;

//Main Window
window -topEdge 30 -title "Display/Hide Local Axis"
-mxb false -s true -rtf false -mb false -mbv false -w 300 -h 100 jh_dispLocalAxis;

//Window content
columnLayout -adjustableColumn true;
separator -w 240 -h 20;
text -label "Utility to display or hide the local rotation axis of the selected object(s)" -fn boldLabelFont;
separator -w 240 -h 25;
button -label "Display Local Axis on selected object(s)" -c "jh_dispAxis 1 0";
button -label "Hide Local Axis on selected object(s)" -c "jh_dispAxis 0 0" -bgc 0.23 0.23 0.23;
separator -w 240 -h 25;
button -label "Display Local Axis on selected object(s) (with hierarchy)" -c "jh_dispAxis 1 1";
button -label "Hide Local Axis on selected object(s) (with hierarchy)" -c "jh_dispAxis 0 1" -bgc 0.23 0.23 0.23;
separator -w 240 -h 25;
window -e -w 300 -h 100 jh_dispLocalAxis;
showWindow jh_dispLocalAxis;
}

global proc jh_dispAxis(int $state, int $hierarchy)
{
//If (with hierarchy) was selected, select the hierarchy
if($hierarchy == 1) select -hi;
//Get the selected object(s)
string $selObj[] = `ls -sl`;
//For each object
for($sel in $selObj)
{
//If the attribute "displayLocalAxis" exist on the current object
if(`attributeExists "displayLocalAxis" $sel`)
{
//Sel the state of the local axis
setAttr ($sel + ".displayLocalAxis") $state;
}
}
}

jh_dispLocalAxis;